Annoying problem with reg add

hozza · 18 Dec 2015 13:58

Okey! I have some code and it's converted to exe and that's is working just fine but,
when I add command REG ADD or REG IMPORT or anything related on REG it stops working!!
and be more specific it works until I convert it to exe!!!
what is the problem????

RG · 18 Dec 2015 14:14

With those few details and no code to view, my guess is that you have a 32/64 bitness problem. One is probably using the 32 bit version of the registry and the other is using the 64 bit version of the registry.
1. Are the machine(s) you are running on 32 or 64 bit?
2. Does it behave the same on both 32 & 64 bit machines?
3. On 64 bit machine try executing from both the 32 bit and 64 bit versions of CMD.exe and I suspect you will see the same problem with one of them.

To fix this on 64 bit machines add the appropriate option to your REG command /reg:32 & /reg:64 See REG QUERY /?

hozza · 18 Dec 2015 15:12

Here is some of the test code this works fine if it is just bat file but when converted to exe it won't work anymore
my machine is 64bit (i tried that what you gues above but no luck!

@echo off
SETLOCAL
set found=
FOR /F "tokens=1-3 delims= " %%a IN ('REG QUERY "HKEY_CLASSES_ROOT\Applications\Somesoftware.exe\shell\open\command"') DO (
 set found=%%c
)

for /f "tokens=1-2" %%a in ("%found%") do (
 set mypath=%%~dpa
)

reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\My_Mods" /v DisplayName /t REG_SZ /d Test_name
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\My_Mods" /v DisplayVersion /t REG_SZ /d 1.22
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\My_Mods" /v InstallLocation /t REG_SZ /d %mypath%mods
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\My_Mods" /v NoModify /t REG_DWORD /d 1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\My_Mods" /v Publisher /t REG_SZ /d MySelf
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\My_Mods" /v UninstallPath /t REG_SZ /d %mypath%mods\Uninstall.exe
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\My_Mods" /v UninstallString /t REG_SZ /d %mypath%mods\Uninstall.exe
Timeout 5
exit

bluesxman · 18 Dec 2015 16:33

If this works as a script, and converting to exe is stopping it from doing so, one could assume that the conversion process is part of the problem. This begs the question, why are you converting it to exe?

foxidrive · 18 Dec 2015 16:59

Above the first "reg add" line put this and then run it compiled to see what it shows:

echo "%found%" "%mypath%"&pause

If that doesn't give you a clue then say how it fails to work too...

hozza · 18 Dec 2015 17:06

well shortly! main reason is that this is just a very small part of code and it holds lots of other files... i'm using this to convert http://www.battoexeconverter.com/

foxidrive · 18 Dec 2015 17:38

How does it fail?

hozza · 19 Dec 2015 10:26

foxidrive wrote:

How does it fail?

tested only that small part! and its working so I had to take some time to look that whole code,
and I did found reason why it was failing there was already one "set found=" , but noticed also
when converting to exe it does make entry to add/remove programs as it should do, but when
I look in actualy path in "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\" there
is nothing!!!! there should be \My_Mods folder with keys but there is not!!!!

foxidrive · 20 Dec 2015 10:55

reg.exe might require more permissions

hozza · 20 Dec 2015 11:53

foxidrive wrote:

reg.exe might require more permissions

Yes I had to change it like this now its working but if you have better solution please feel free to modify!!!

@echo off
TITLE Searching Path
SETLOCAL
set found=
FOR /F "tokens=1-3 delims= " %%a IN ('REG QUERY "HKEY_CLASSES_ROOT\Applications\SomeSoftware.exe\shell\open\command"') DO (
 set found=%%c
)

for /f "tokens=1-2" %%a in ("%found%") do (
 set mypath=%%~dpa
)
Echo %mypath%
TITLE Adding Registry settings
Echo Windows Registry Editor Version 5.00 >>"%mypath%test_folder\regfile.reg"
Echo. >>"%mypath%test_folder\regfile.reg"
Echo [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\My_Mods] >>"%mypath%test_folder\regfile.reg"
Echo "UninstallPath"="%mypath%test_folder\Uninstall.exe" >>"%mypath%test_folder\regfile.reg"
Echo "UninstallString"="%mypath%test_folder\Uninstall.exe" >>"%mypath%test_folder\regfile.reg"
REG IMPORT "%mypath%test_folder\regfile.reg"

Last edited by hozza (20 Dec 2015 11:55)

foxidrive · 20 Dec 2015 14:48

hozza wrote:

please feel free to modify!!!

This isn't really better, but with your character set you can use this style of file creation.

@echo off
TITLE Searching Path
SETLOCAL
set found=
FOR /F "tokens=1-3 delims= " %%a IN ('REG QUERY "HKEY_CLASSES_ROOT\Applications\SomeSoftware.exe\shell\open\command"') DO (
 set found=%%c
)

for /f "tokens=1-2" %%a in ("%found%") do (
 set mypath=%%~dpa
)
Echo %mypath%
TITLE Adding Registry settings
(
Echo Windows Registry Editor Version 5.00
Echo(
Echo [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\My_Mods]
Echo "UninstallPath"="%mypath%test_folder\Uninstall.exe"
Echo "UninstallString"="%mypath%test_folder\Uninstall.exe"
)>"%mypath%test_folder\regfile.reg"
REG IMPORT "%mypath%test_folder\regfile.reg"
del "%mypath%test_folder\regfile.reg"

It also looks a lot like the second for loop can be eliminated -

Does this provide the variable you are after?

@echo off
FOR /F "tokens=1-3 delims= " %%a IN ('REG QUERY "HKEY_CLASSES_ROOT\Applications\SomeSoftware.exe\shell\open\command"') DO (
 set "mypath=%%~dpb"
)
Echo "%mypath%"
pause

Last edited by foxidrive (20 Dec 2015 14:49)

hozza · 20 Dec 2015 18:02

foxidrive wrote:

Does this provide the variable you are after?

@echo off
FOR /F "tokens=1-3 delims= " %%a IN ('REG QUERY "HKEY_CLASSES_ROOT\Applications\SomeSoftware.exe\shell\open\command"') DO (
 set "mypath=%%~dpb"
)
Echo "%mypath%"
pause

Yes it does!! and noticed later that there was a proplem with 64 and 32 bit system like RG wrote earlier but that also now corrected so now all working just fine!
although i try to get this code working for almost a week and I was going to rip hair of my head but as the saying goes All's Well That Ends Well

THANK YOU VERY MUCH: foxidrive and RG

SS64 Forum

#1 18 Dec 2015 13:58

Annoying problem with reg add

#2 18 Dec 2015 14:14

Re: Annoying problem with reg add

#3 18 Dec 2015 15:12

Re: Annoying problem with reg add

#4 18 Dec 2015 16:33

Re: Annoying problem with reg add

#5 18 Dec 2015 16:59

Re: Annoying problem with reg add

#6 18 Dec 2015 17:06

Re: Annoying problem with reg add

#7 18 Dec 2015 17:38

Re: Annoying problem with reg add

#8 19 Dec 2015 10:26

Re: Annoying problem with reg add

#9 20 Dec 2015 10:55

Re: Annoying problem with reg add

#10 20 Dec 2015 11:53

Re: Annoying problem with reg add

#11 20 Dec 2015 14:48

Re: Annoying problem with reg add

#12 20 Dec 2015 18:02

Re: Annoying problem with reg add

Board footer