cmd game~ ESCAPE

Microsoft Windows
Post Reply
User avatar
MigrationUser
Posts: 336
Joined: 2021-Jul-12, 1:37 pm
Contact:

cmd game~ ESCAPE

Post by MigrationUser »

26 Feb 2015 00:54
landon997

this is a game i have been working on for a while now and i would like to release it to the public its called ESCAPE
its really great and has undergone many updates
i would like to release all the updates right now but i dont have a paid for mediafire account
it will work on win7 and win8 idk if it will work on anything below that

here is the latest(V2.2) download you must have winrar to download - https://www.mediafire.com/file/bqtcs3id ... e.rar/file

link to the code(V2.2) - https://www.mediafire.com/file/56bpdcbj ... 2.bat/file

link to the changelog (V2.2) - https://www.mediafire.com/file/d239wkzh ... 2.txt/file

download WINRAR - https://www.rarlab.com/download.htm

and here is the website - https://sites.google.com/site/cmdescapegame/home

if you want to see it on gamejolt - https://gamejolt.com/games/escape-v2-3/54740

also when you download, it may say that windows is protecting you just click where the arrow is pointing in the pictures

Image
Image

(btw im not trying to destroy your computer... its just a GAME)

pece ~ john

Last edited by landon997 (19 Mar 2015 13:07)

----------------------------

#2 26 Feb 2015 00:56
landon997

here is the code to the game if u want to copy and paste into a batch file
THIS IS V2.3
CHANGELOG AT BOTTOM

Code: Select all

::           __________________________________________________________
::           \   __________________________________________________   /
::            | |                                                  | |
::            | |                      ESCAPE                      | |
::            | |                       v2.3                       | |
::            | |                  by John Walker                  | |
::            | |                                                  | |
::            | |           Code update by Shadow Thief (V2.2)     | |
::            | |                                                  | |
::            | | Send comments or concerns to i8ab2nite@gmail.com | |
::            | |    Updated or altered code must retain credit    | |
::            | |       to the original author,  John Walker       | |
::            | |__________________________________________________| |
::           /________________________________________________________\

:: ASCII ART CREDITS
:: -----------------
:: Butler - http://www.retrojunkie.com/asciiart/people/butlers.htm
:: Lightning - http://www.retrojunkie.com/asciiart/nature/lightnng.htm
:: Getaway - http://www.retrojunkie.com/asciiart/vehicles/cars.htm
:: Police car - http://www.asciiworld.com/-Police,150-.html
:: Bust - http://www.retrojunkie.com/asciiart/people/police.htm

@echo off
setlocal enabledelayedexpansion

:: Define delay macros to shrink the code a bit
for /L %%A in (1,1,5) do set "sleep_%%A=timeout /t %%A > nul"

:: Define all possible secret codes
set code[0][0]=start&set code[0][1]=begin
set code[1][0]=color&set code[1][1]=story2
set code[2][0]=cop&set code[2][1]=story3
set code[3][0]=john&set code[3][1]=sec1
set code[4][0]=ascii&set code[4][1]=sec2

:: Display the warning, title, and main menu
title ESCAPE
mode con cols=80 lines=30
cls
color 0C
for /L %%A in (1,1,10) do echo.
echo                                     WARNING!
echo.
echo                 THIS GAME CONTAINS FLASHING LIGHTS AND COLORS.
echo           DO NOT PLAY OR VIEW THIS GAME IF YOU SUFFER FROM EPILEPSY.
%sleep_5%

:startGame
for /L %%A in (1,1,9) do (
	cls
	color 0%%A
	for /L %%B in (1,1,10) do echo.
	call :center "- ESCAPE -" 10
	call :center "version 2.2 beta" 16
	ping -n 1 127.0.0.1>nul
)
color 0C
for /L %%A in (1,1,5) do echo.
call :center MENU 4
call :center -------------- 14
call :center "[1] Begin Game" 14
call :center "[2] Enter Code" 14
call :center "[3] Credits   " 14
call :center "[4] Quit      " 14
choice /C:1234 /D 3 /T 10 /N>nul

:: Process menu choices using %errorlevel% instead of errorlevel to get
:: around that nasty "bug" where you would otherwise have to list the
:: errorlevels in reverse order. Literally just personal preference.
if %errorlevel% equ 1 goto begin
if %errorlevel% equ 2 goto enterCode
if %errorlevel% equ 3 set quit=0&goto credits
if %errorlevel% equ 4 exit /b

:: Enter a secret password that will take you to some predetermined part of the story
:: or the credits
:enterCode
cls
color 0A
for /L %%B in (1,1,10) do echo.
echo                                    - ESCAPE -
echo                                 version 2.2 beta
echo.
echo                        ::::::::::::::::::::::::::::::::::
echo                        :: E  N  T  E  R     C  O  D  E ::
echo                        ::::::::::::::::::::::::::::::::::
echo.
set /p "passcode=_                        "
for /L %%A in (0,1,4) do if [%passcode%]==[!code[%%A][0]!] goto !code[%%A][1]!

:: If we get to this part, an invalid code has been entered
echo Unrecognized code. Please enter START to begin the game.
%sleep_3%
goto enterCode

:begin
cls
color 0A
:: This doesn't actually matter
set /p name=What will be your charater's name? 
echo Ok, your charater's name will be %name%.
%sleep_3%
cls
color 80
for /L %%A in (1,1,19) do echo.
echo It was a dark and stormy night....... of course.
%sleep_3%
cls
call :ascii_butler
echo A butler was working hard in his master's mansion...
%sleep_4%
color 08
echo suddenly, his light went out^^!
%sleep_3%

:: This doesn't matter either
cls
set /p b=What should he do? 
%sleep_1%
echo The butler feels his way around the room, trying to find a match.
%sleep_1%
echo There is a flash of lightning^^!
%sleep_2%
cls
color 76
call :ascii_lightning
%sleep_1%
color 06
%sleep_2%
cls
color 0C 
call :printn "The butler falls to the ground."
%sleep_1%
call :printn "."
%sleep_1%
call :printn "."
timeout /t 2 > nul
echo dead.
%sleep_3%
cls
color 0A
echo You, %name%, are the murderer.
%sleep_2%
echo You had your reasons.
%sleep_2%
call :printn "You jump out the window landing the the pond below... "
%sleep_2%
echo as planned.
%sleep_2%
echo.
echo You meet your getaway driver in the driveway
%sleep_2%
echo and speed off down the road, far away from the house.
call :ascii_car
%sleep_2%
echo.
echo Sadly for you, no one escapes the law.
%sleep_4%
cls
color 0C
echo The next day, you are eating your lunch behind a tree 
echo when the police pull up to your car.
%sleep_4%
call :ascii_cruiser
for /L %%A in (1,1,2) do (
	%sleep_1%
	color 09
	%sleep_1%
	color 0C
)
echo.
call :printn "Your getaway driver was in the car. "
%sleep_4%
echo Luckily for you, he took the blame.
%sleep_4%
cls
color 0A
echo You could wait the whole thing out, hiding behind your tree...
%sleep_4%
echo but you are nervous.
echo.
set /p c=What should you do? 
call :printn "You decided to %c%."
%sleep_4%
echo .. that was a foolish decision.
%sleep_4%
echo.
echo When the cops noticed you, you knew you should have thought things through.
%sleep_4%
call :ascii_bobby
%sleep_4%
cls
echo You sprint out into the woods^^!
%sleep_4%

:: Time for a minigame!
cls
for /L %%A in (1,1,12) do echo.
call :center "MINIGAME  TIME" 14
:minigame
%sleep_4%
echo.
echo Press W to jump over the logs^^! If you trip, the police will catch you^^!
echo Ready?
pause
:minigame1
cls
for /L %%A in (1,1,3) do (
	%sleep_1%
	choice /C:TW /T 1 /D T /M:"PRESS W" /N
	if !errorlevel! equ 1 goto story2
)

:: You completed the minigame! You could escape, but John might have other plans...      which i DO
cls
echo You make it through the forest^^!
%sleep_2%
echo Unfortunately, when you turn to see if you are being followed... 
%sleep_2%

:story2
echo You trip on a rock.
%sleep_3%

:loop
cls
for /L %%A in (1,1,12) do echo.
call :ascii_rise
for /L %%A in (1,1,3) do (
	title Ouch!
	for /L %%B in (1,1,9) do (
		color 0%%B
		ping -n 1 -w 1000 127.0.0.1 >nul
	)
	title Head... hurts...
)
color 0A
set /p loop=Wake Up?
if /i %loop%==r goto story3
goto loop

:story3
color 0F
cls
for /L %%A in (1,1,12) do echo.
call :center "WAKE  UP" 8
%sleep_2%
call :ascii_bobby
call :printn "You are caught..."
%sleep_1%
echo darn.
%sleep_3% 
cls
title ESCAPE
echo Use the code "cop" at the begining to skip to here.
%sleep_3% 
cls
call :printn "You are dragged back to the police car... "
%sleep_2%
echo half-conscious...
%sleep_2%

:cell1
echo.
echo When you wake up, you find yourself inside a jail cell.
%sleep_3%
cls
echo How will you escape?
echo (B)omb your way out
echo (D)ig your way out
choice /C:BD /N >nul
if %errorlevel% equ 1 goto bomb
if %errorlevel% equ 2 goto dig

:: In close quarters like these? Yeah, that'll work.
:bomb
echo.
echo.
echo You decide to blow up the bars. Good plan. You ^(somehow^) acquire explosives,
echo put them on the bars, and light the fuse...
%sleep_2%
echo You've blown yourself up. Nice going.
%sleep_2%
echo (F)orfeit the game
echo (M)ake a different choice
choice /C:FM /N >nul
if %errorlevel% equ 1 goto title
if %errorlevel% equ 2 cls&goto cell1
 
:: I see somebody's been watching The Shawshank Redemption
:: Nope i didnt even know what that was untill i just googled it... 
:dig
cls
echo After a lot of work, you manage to dig your way out of the prison... 
%sleep_1%
echo or so you think.
%sleep_2%
echo.
echo.
echo You are in the prison courtyard.
echo (H)ide in an alcove
echo (R)un for it^^!
echo (S)earch for a weapon
choice /C:HRS /N >nul
if %errorlevel% equ 1 goto hide
if %errorlevel% equ 2 goto escape
if %errorlevel% equ 3 goto gun

:: I am the night
:hide
cls
echo You dive into an alcove about a second before a guard enters the courtyard.
%sleep_2%
echo His back is turned and you could easily sneak up on him...
echo (A)ttack the guard
echo (W)ait for him to leave
choice /C:AW /N >nul
if %errorlevel% equ 1 goto fight1
if %errorlevel% equ 2 goto whimper

:whimper
echo.
echo You wait for him to continue his patrol... suddenly, he turns around^^!
for /L %%A in (1,1,6) do echo.
call :center BUSTED 6
echo.
echo (F)orfeit the game
echo (M)ake a different choice
choice /C:FM /N >nul
if %errorlevel% equ 1 goto title
if %errorlevel% equ 2 goto hide

:: No-scope 360 headshot, yo
:fight1
cls
color 0C
call :printn "You decide to FIGHT."
%sleep_1%
call :printn "."
%sleep_1%
call :printn ". "
echo you choke the guard and take his gun.
%sleep_2%
echo.
call :center "+1 swag" 7
%sleep_2%
goto gtfo

:: .yaw gnorW
:escape
cls
call :printn "You run to the prison exit... "
%sleep_2%
echo locked^^!
%sleep_1%
call :printn "You turn around "
%sleep_2%
echo to find a guard.
echo.
echo (F)orfeit the game
echo (M)ake another choice
choice /C:FM /N >nul
if %errorlevel% equ 1 goto title
if %errorlevel% equ 2 goto dig 

:gun
cls
echo You search around for a gun... and find an unlocked cabinet full of them.
%sleep_2%
echo What a terrible prison.
%sleep_2%

:gtfo 
cls
color 0F
call :printn "So there you are, "
%sleep_2%
call :printn "standing in the couryard,"
%sleep_2%
echo gun in your hand...
%sleep_5%
cls
echo so
%sleep_1%
cls
echo so .
%sleep_1%
cls
echo so ..
%sleep_1%
cls
echo so ...
ping -n 1.5 -w 100000 127.0.0.1 > nul
cls
echo so ... what
ping -n 1.5 -w 100000 127.0.0.1 > nul
cls
echo so ... what do
ping -n 1.5 -w 100000 127.0.0.1 > nul
cls
echo so ... what do you
ping -n 1.5 -w 100000 127.0.0.1 > nul
cls
echo so ... what do you do now
ping -n 1.5 -w 100000 127.0.0.1 > nul
cls
echo so ... what do you do now?
%sleep_3%
cls
echo well DUH
%sleep_1%
cls
echo Do what any prisoner does when he escapes from jail
%sleep_3%
cls
echo .
%sleep_1%
cls
echo ..
%sleep_1%
cls
echo ...
%sleep_1%
cls
echo RUN TO MEXICO!
%sleep_1%
echo (insert mexican trumpet music here)
%sleep_1%
echo    ()
echo  _/_ \_
echo ( 0 - o)           ______
echo   -()-            (MEHICO)
echo    /\              \    /
echo                     (__)
%sleep_2%
cls
echo or should you?
%sleep_1%
echo maybe you could go to canada      
%sleep_3%
echo and you heard that everything in canada is free!... or somthing
%sleep_3%
set/p gtfo= so what do you choose? (c)anada or (m)exico :
if %gtfo%==c goto canada
if %gtfo%==m goto mexico


:: btw canada is the good ending
:canada
cls
echo you decide
%sleep_1%
cls
echo you decide to go
%sleep_1%
cls
echo you decide to go to canada
%sleep_1%
call :ascii_canada
%sleep_2%









































echo Thus ends the game^^! More coming soon^^!
echo                                 ~John   
pause
goto credits

:: secret codes

:sec1
cls
color 0F
for /L %%A in (1,1,12) do echo.
call :center "YOU  WIN" 8
%sleep_2%
call :center "but you missed the whole game" 29
%sleep_4% 
cls
goto credits

:sec2
cls
echo Here is all the ASCII art used so far, in order of appearance
%sleep_3% 
cls
call :ascii_butler
%sleep_2%
cls
call :ascii_lightning
%sleep_2%
cls
call :ascii_car
%sleep_2%
cls
call :ascii_cruiser
%sleep_2%
cls
call :ascii_bobby
%sleep_2%
cls
call :ascii_rise
%sleep_2%
cls
call :ascii_canada
%sleep_2%
cls
echo the colors here do not match the colors used in the game 
%sleep_2%
for /L %%A in (1,1,2) do (
	cls
	call :printn "Warping to beginning."
	%sleep_1%
	call :printn "."
	%sleep_1%
	echo .
)
goto startGame

:: Displays the credits
:credits
cls
:: Set up some arraylikes for easier looping
:: creditObject <index> <title> <tite_length> <ascii_code> <echo._count> <url> <url_length>
call :creditObject 0 "'Butler' - JGS'" 14 butler 4 http://www.retrojunkie.com/asciiart/people/butlers.htm 55
call :creditObject 1 "'Lightning' - Anonymous" 23 lightning 0 http://www.retrojunkie.com/asciiart/nature/lightnng.htm 55
call :creditObject 2 "'Car' - Jaap Peters" 19 car 13 http://www.retrojunkie.com/asciiart/vehicles/cars.htm 53
call :creditObject 3 "'Police Cruiser' - Anonymous" 28 cruiser 8 "http://www.asciiworld.com/-Police,150-.html" 43
call :creditObject 4 "'English Bobby' - JGS" 21 bobby 13 http://www.retrojunkie.com/asciiart/people/police.htm 53

color 0F
for /L %%A in (1,1,13) do echo.
call :center CREDITS 7

for /L %%A in (0,1,4) do (
	%sleep_4%
	cls
	echo.
	call :center "ASCII  ART" 10
	call :center "----------" 10
	call :center !art[%%A].title! !art[%%A].t_length!
	call :ascii_!art[%%A].code!
	for /L %%B in (1,1,!art[%%A].echos!) do echo.
	call :center !art[%%A].url! !art[%%A].u_length!
)

%sleep_3%
cls
for /L %%A in (1,1,12) do echo.
call :center CODE 4
call :center ------ 6
call :center "John  Walker" 12
%sleep_3%
cls
for /L %%A in (1,1,12) do echo.
call :center "EVERYTHING  ELSE" 16
call :center ---------------- 16
call :center "John  Walker" 12
%sleep_3%
cls
for /L %%A in (1,1,12) do echo.
call :center "WITH HELP FROM" 14
call :center -------------- 14
call :center "http://ss64.org/viewtopic.php?pid=8238#p8238" 44
%sleep_3%
cls
for /L %%A in (1,1,12) do echo.
call :center "SPECIAL THANKS" 14
call :center -------------- 14
call :center "SHADOW THIEF" 12
%sleep_3%
goto startGame

:: -----------------------------------------------------------------------------
::                        S  U  B  R  O  U  T  I  N  E  S
:: -----------------------------------------------------------------------------

::::::::::::::::::::::::::::::::::::::::::::::::::
:: Centers text based on a provided string length
:: Arguments: %1 - String to center
::            %2 - Length of string
::::::::::::::::::::::::::::::::::::::::::::::::::
:center
set center_string=%~1
set string_length=%2
set /a string_length=%string_length%/2
set /a buffer_cut=40+%string_length%
set buffer_text=                                                                                %center_string%
set buffer_text=!buffer_text:~-%buffer_cut%!
echo !buffer_text!
goto :eof

::::::::::::::::::::::::::::::::::::::::::::::::::
:: Creates credit page objectlikes
:: Arguments: %1 - Index
::            %2 - Title
::            %3 - Title Length
::            %4 - ASCII Code Name
::            %5 - echo. Buffer Length
::            %6 - Source URL
::            %7 - Source URL Length
::::::::::::::::::::::::::::::::::::::::::::::::::
:creditObject
set art[%1].title=%2
set art[%1].t_length=%3
set art[%1].code=%4
set art[%1].echos=%5
set art[%1].url=%6
set art[%1].u_length=%7
goto :eof

::::::::::::::::::::::::::::::::::::::::::::::::::
:: Echos a string without a newline at the end
:: Arguments: %1 - String to echo
::::::::::::::::::::::::::::::::::::::::::::::::::
:printn
set /p=%~1<nul
goto :eof

:: Subroutines for displaying ASCII art to reduce the amount of redundant code
:ascii_butler
echo.
echo                                  .--.              
echo                                 /    \             
echo                                ## a  a       _     
echo                                (   '._)     ^|_^|    
echo                                 ^|'-- ^|      ^| ^|    
echo                               _.\___/_   ___^|_^|___ 
echo                             ."\^> \Y/^|^<'.  '._.-' 
echo                            /  \ \_\/ /  '-' /      
echo                            ^| --'\_/^|/ ^|   _/       
echo                            ^|___.-' ^|  ^|`'`         
echo                              ^|     ^|  ^|            
echo                              ^|    / './            
echo                             /__./` ^| ^|             
echo                                \   ^| ^|             
echo                                 \  ^| ^|             
echo                                 ;  ^| ^|             
echo                                 /  ^| ^|             
echo                                ^|___\_.\_           
echo                                `-"--'---'          
goto :eof

:ascii_lightning
echo                                 .-~*~--,.   .-.            
echo                         .-~-. ./OOOOOOOOO\.'OOO`9~~-.      
echo                       .`OOOOOO.OOM.OLSONOOOOO@@OOOOOO\     
echo                      /OOOO@@@OO@@@OO@@@OOO@@@@@@@@OOOO`.   
echo                      lOO@@@WWWW@@@@OOWWW@WWWW@@@@@@@OOOO). 
echo                    .-'OO@@@@WW@@@W@WWWWWWWWOOWW@@@@@OOOOOO}
echo                   /OOO@@O@@@@W@@@@@OOWWWWWOOWOO@@@OOO@@@OOl
echo                  lOOO@@@OO@@@WWWWWWW\OWWWO\WWWOOOOOO@@@O.' 
echo                   \OOO@@@OOO@@@@@@OOW\     \WWWW@@@@@@@O'. 
echo                    `,OO@@@OOOOOOOOOOWW\     \WWWW@@@@@@OOO)
echo                     \,O@@@@@OOOOOOWWWWW\     \WW@@@@@OOOO.'
echo                       `~c~8~@@@@WWW@@W\       \WOOl\UO-~'  
echo                            (OWWWWWW@/\W\    ___\WO)        
echo                              `~-~''     \   \WW=*'         
echo                                        __\   \             
echo                                        \      \            
echo                                         \    __\           
echo                                          \  \              
echo                                           \ \              
echo                                            \ \             
echo                                             \\             
echo                                              \\            
echo                                               \            
echo                                                \           
goto :eof

:ascii_canada

echo  _
echo(_)
echo l_____________________________________
echo  l&&&&&&                         &&&&&&l
echo  l&&&&&&                         &&&&&&l
echo  l&&&&&&                         &&&&&&l
echo  l&&&&&&          .\^/.          &&&&&&l
echo  l&&&&&&        . l   l .        &&&&&&l
echo  l&&&&&&        l\l   l/l        &&&&&&l
echo  l&&&&&&     .--'       '--.     &&&&&&l
echo  l&&&&&&      \           /      &&&&&&l
echo  l&&&&&&       >         <       &&&&&&l
echo  l&&&&&&      '-l/--l--\l-'      &&&&&&l
echo  l&&&&&&            l            &&&&&&l
echo  l&&&&&&                         &&&&&&l
echo  l&&&&&&                         &&&&&&l
echo  l&&&&&&_________________________&&&&&&l
echo  l~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
goto:eof

:ascii_car
echo.
echo                     _________________________
echo                 __ /  ,-----------. .-------.`.
echo                   /  /      //    l ll       l.`.
echo              __  / '------++------' l`---------[)l`----..___
echo              __ :]            _     l            l    ______"""-.
echo                _:]__________ l_l    1             l   ,,----.^\___l
echo                1___ /',--. ^\       1_____________l  // ,--.^\____l
echo                 \_-/'1    1: \----------------------'l l    l:l_/
echo                    \ `---'/:'----------------------' \ `---'/
echo                     `'---'                            `'---'
goto:eof

:ascii_cruiser
echo.
echo                              ______________________
echo                             (eeeeeee uuuuu aaaaaaaa)
echo                         _/~~~~~~~~~~~~~~~~~~~~~~~~~~~~\
echo                        /~                             ~\
echo                      .~                                 ~
echo                  ()\/_____                           _____\/()
echo                 .-''      ~~~~~~~~~~~~~~~~~~~~~~~~~~~     ``-.
echo               .-~              __________________              ~-.
echo               `~~/~~~~~~~~~~~~TTTTTTTTTTTTTTTTTTTT~~~~~~~~~~~~\~~'
echo               l l l #### #### ll l l l [] l l l ll #### #### l l l
echo               ;__\l___________l++++++++++++++++++l___________l/__;
echo               (~~====___________________________________====~~~)
echo                \------_____________[CHIP 911]__________-------/
echo                   l      ll         ~~~~~~~~       ll      l
echo                    \_____/                          \_____/
goto :eof

:ascii_bobby
echo.
echo                                     .'`"`'.
echo                                    /   , , \                       
echo                                   l/   a` a l
echo                                   (      _\ l
echo                                    \    __  ;
echo                                   l\   .  /
echo                                 _.'\ '----;'-.
echo                             _.-'  O ;-.__.'\O `o.
echo                            /o \      \/-.-\/l    \
echo                           l    ;,     '.l\l /     1
goto :eof

:ascii_rise
for /L %%B in (1,1,5) do (
	echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	echo -------------------------------------------------------------------------------
	echo ```````````````````````````````````````````````````````````````````````````````
	echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	echo ===============================================================================
	echo +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
)
echo @@@@  P R E S S  "R"  T O   W A K E   U P  @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
goto :eof 




====================================
CHANGELOG===============V2.3===========
====================================

1. added to story (very little)
2. got used to this type of code!
3. sry no new ascii art prob some in V3.0 but that will be a while =/
4. added some more text animations !!
5. also the story part i added is rather broken

Last edited by landon997 (05 May 2015 23:29)

----------------------------

#3 26 Feb 2015 05:31
Shadow Thief

You know we have code tags, right? For code?
----------------------------

#4 26 Feb 2015 05:46
Shadow Thief


Just played it. It's alright. A few thoughts...

What does having a premium Mediafire account have to do with anything? I have one and the only difference between it and a non-premium account is that you get more space. If you're that concerned about it, get an account at mega.co.nz instead. You'll get 50GB of space for free.

Fix the grammar. There are mistakes in literally every sentence.

Use MODE CON COLS to adjust the screen to a decent size; right now in the choices section, all of the lines run over to the next line in the middle of a word and it's very hard to read.

Consider using the CHOICE command for players to enter their choices, or at least use IF /I so that they can enter both r and R to wake up.

You seem very concerned about making sure that we know that you wrote the game, but you never credit the people who created the ascii art, you just say it wasn't you. Actually credit them.

On a related note, the blanket phrase for the credits should be "respective owners," not "respectful owners."

Go with 0C instead of 04 for the intro color; dark red is hard to read on black.

Last edited by Shadow Thief (26 Feb 2015 05:57)

----------------------------

#5 26 Feb 2015 13:43
landon997


thx for the input and yes i know there is bad grammar also in order to send folders you have to have a paid mediafire account

also i will change the color to 0C and change respectful owners to respective owners

i will try to find the creators of the acsii art and cite them
and i will mess around with the if commands and try to find out how to use mode con cols

thanks 4 the input
pece~ john

----------------------------

#6 26 Feb 2015 13:44
landon997


i repeated so many words in that post =/
#hidingfromthegrammarnazis

----------------------------

#7 26 Feb 2015 13:57
Shadow Thief
landon997 wrote:

thx for the input and yes i know there is bad grammar also in order to send folders you have to have a paid mediafire account
I recommend just sticking everything in a zip file instead. You still get the folder, but there's only one file so you don't need to pay for anything.

----------------------------

#8 26 Feb 2015 13:57
landon997


alo i added some "hidden" codes you can put in at the begining if you use the code acsii it will show all the art used in v2.1 it will have the respective owners cited

----------------------------

#9 26 Feb 2015 14:15
Shadow Thief

I'm actually in the process of making a few tweaks if you don't mind waiting a bit.

----------------------------

#10 26 Feb 2015 14:24

landon997

thats fine make shure you use V2.1 i just updated it and i wont make any changes till ur done

i will work on the mediafire stuff

----------------------------

#11 26 Feb 2015 14:39

landon997

OK i have all the stuff in 1 .rar file availible for download at the top of this page

you must have winrar or a .rar extractor of some sorts

----------------------------

#12 26 Feb 2015 16:48
Shadow Thief


Alright, it's finally done. https://mega.co.nz/#!iJ8n1Qjb!3_ToGTFOj ... 0LQEhcosDo

I shrunk it by about 7 KB and added some subroutines I think you'll like at the bottom.
I converted the timeout commands into macros so that you only have to type %sleep_1%, %sleep_2%, etc instead of the whole command - this goes through %sleep_5%.
I had to enable delayed expansion to optimize the credits sequence so any time you want to display an exclamation point in regular text now, you have to use ^^! instead.
I also finished the log-jumping minigame, but I wasn't sure if you wanted escape that way to be a valid way of finishing the game so I wrote it so that you get caught anyway.
If you use the :center or :printn subroutines, remember to put the string in quotes.

I replaced the input via set /p commands with the CHOICE command. If you're using Windows XP, this adds the new feature of breaking absolutely everything, since XP doesn't come with that command natively. That said, support for XP ended forever ago and the only reason to still be using it is for work - and you shouldn't be playing games at work anyway.

----------------------------

#13 26 Feb 2015 19:12

landon997

yeah i never intended for the game to end if you won the minigame even if you dont mess up you still trip on the rock and the same thing happens

also GREAT job ... i not tht good at .bat codes considering this IS my first game but i will continue to use this "style" of batch code :D :D

btw i wont officialy release V2.2 quite yet im going to figure out the code first XD

i fixed a mistake you put goto title but you changed :title to :startGame so i would be goto startGame, that was causing the game to crash after viewing th ascii art

pece ~ john

(also i have no idea what Shawshank Redemption is =/ )

Last edited by landon997 (26 Feb 2015 19:40)

----------------------------

#14 26 Feb 2015 19:52
landon997

i had to change (square brackets here)d(squarebracketshere)ig to (d)ig and same with bomb

because it would not allow me to post is

----------------------------

#15 26 Feb 2015 20:53
Shadow Thief

If you had used ^

Code: Select all

 tags, you wouldn't have that problem.

----------------------------

#16 26 Feb 2015 22:47
landon997


=p lol im sorta noob at this

----------------------------

#17 27 Feb 2015 00:38

landon997

i finaly figured out what you meant by code tags XD

----------------------------

#18 28 Feb 2015 19:04
landon997


im sry ths hasnt been updated in a while im working on school and dont rly have time

(aka addicted to minecraft)

----------------------------

#19 01 Mar 2015 19:31
Shadow Thief

[quote]landon997 wrote:

    in a while
[/quote]
It's only been three days...

but I admire your need to keep us updated.

----------------------------

#20 02 Mar 2015 01:29
landon997

yup im working on V2.3 as i ... type

----------------------------

#21 18 Mar 2015 01:05
landon997


i have been inactive for a while now maybe an update this friday?

???? maybe...somthing BIGGER

----------------------------

#22 18 Mar 2015 20:23
landon997


ok phew v2.3 is ready for release will release it in a couple hours

nothing big

bug fixes/added to story

also im probably going to finish the game at v3.0 and start working on something else

~john walker

----------------------------

#23 31 Mar 2015 01:12
landon997


ok wooo! i added escape V2.2 to GAMEJOLT

link-------) https://gamejolt.com/games/escape-v2-3/54740

----------------------------

#24 29 Apr 2015 00:23
landon997


ok and done i have been inactive for about a month but i got stuff done! updated to 2.3 you can find it on gamejolt ---) https://gamejolt.com/games/escape-v2-3/54740

also released another batch game on gamejolt ---) http://gamejolt.com/games/other/hirschquest-monday-of-reckoning/63452/

----------------------------

#25 02 May 2015 07:51
Shadow Thief

Pretty much just the same thoughts as last time - cite the new ASCII art, use the %printn% function to eliminate the need to cls/echo/cls/echo when you're animating text, and use choice instead of set /p

Also, a change log should include all changes up to that point, not just the most recent ones.

My biggest complaint is that you don't even have a label for running to Mexico. I get that you're supposed to lose if you run to Mexico, but right now the game just crashes because there's no label.

And what is this supposed to be?

    ()
  _/_ \_
 ( 0 - o)           ______
   -()-            (MEHICO)
    /\              \    /
                     (__)

----------------------------

#26 02 May 2015 07:56
Shadow Thief


Oh, and you've got some ping commands where you say ping -n 1.5 -w 100000 127.0.0.1 > nul

That means that you're telling the computer to ping 127.0.0.1 one and a half times. It should be obvious why that won't work properly.

----------------------------

#27 03 May 2015 06:08
foxidrive


You're very helpful Shadow Thief, good on you.

I'm not sure if this comment is off topic, it's a rant, but I really dislike going to another website to download text batch script which should be posted here in the first place.

Last edited by foxidrive (03 May 2015 06:10)

----------------------------

#28 05 May 2015 23:23

landon997

foxdrive thats why i post the whole game right here im trying to make it as easy as possible to get the game
also its a rush update i know but i intend to polish it when the game is done (V3.0) also running to mexico will be an alternate ending and i just have't added anything to that part  yet i will finish the canada ending at V2.7ish then do the mexico ending the canada ending will be the good ending btw

p.s. plz remember im new to batch stuff and im only 13 so no hates, this is also my first game soooo

----------------------------

#29 05 May 2015 23:36
landon997


also shadow thief plz ignore all the "ascii" i put in there its just somthin i made because i was off line and could not get some good ascii art =P

----------------------------

#30 06 May 2015 14:51
foxidrive

[quote]landon997 wrote:

    p.s. plz remember im new to batch stuff and im only 13 so no hate
[/quote]
No problem.  I see your code has been posted at the top, beauty.
Post Reply